
 1000  *SAVE S.LIST MAJOR LABELS
 1010  *--------------------------------
 1020  SRCP   .EQ $DD,DE
 1030  *--------------------------------
 1040  PARSE.LINE.RANGE    .EQ $DEAF OR 1EAF
 1050  CMP.SRCP.ENDP       .EQ $DF11 OR 1F11
 1060  LIST.CURRENT.LINE   .EQ $D737 OR 1737
 1070  *---LINK COMMAND-----------------
 1080  INIT   LDA $C083    ENABLE LANGUAGE CARD
 1090         LDA $C083
 1100         LDA #USR.LIST    SET UP USR VECTOR
 1110         STA $D007
 1120         LDA /USR.LIST
 1130         STA $D008
 1140         RTS
 1150  *---USR COMES HERE---------------
 1160  USR.LIST
 1165         JSR PARSE.LINE.RANGE
 1170  .1     JSR CMP.SRCP.ENDP
 1180         BCC .2
 1190         RTS
 1200  .2     LDY #3       POINT TO FIRST CHAR
 1210         LDA (SRCP),Y
 1220         BPL .5       NOT TOKEN
 1230         CMP #$C0
 1240         BCS .4       REPEAT TOKEN
 1250  .3     LDY #0       SKIP TO NEXT LINE
 1260         LDA (SRCP),Y LINE LENGTH
 1270         CLC
 1280         ADC SRCP
 1290         STA SRCP
 1300         BCC .1
 1310         INC SRCP+1
 1320         BNE .1       ...ALWAYS
 1330  *--------------------------------
 1340  .4     LDY #5       POINT AT RPTD CHAR
 1350         LDA (SRCP),Y
 1360  .5     CMP #'A'
 1370         BCC .3       NOT LETTER
 1380         CMP #'Z'+1
 1390         BCS .3       NOT LETTER
 1400         JSR LIST.CURRENT.LINE
 1410         JMP .1
 1420  *--------------------------------

